/*--------------------------------------------------
   探索的ポジショニング分析を行うＳＡＳマクロ

   著者：豊田秀樹（早稲田大学）
   ----------------------------------------------

   パラメータが用意されている状態では

   %inc 'このファイル自身のファイル名';
   %position ; 
   run;

   で利用可能である．
   パラメータが必要な場合は
   %inc 'このファイル自身のファイル名';
   %position(
              ti      = 'タイトル'     ,
              dfn     = '生データ'     ,
              kei     = 形容詞数       ,
              gai     = 概念数         ,
              mit     = 最大繰り返し   ,
              mfu     = 最大関数評価数 ,
              ke_m_in = 観測変数切片初期値（尺度の真ん中の値）
             ) ; 
   run;

   で利用する
-----------------------------------------------*/

%macro position(
            ti      = '探索的ポジショニング分析',
            dfn     = 'h:\自作文章\執筆論文\印象確認\mast.DAT',
            kei     = 6    ,
            gai     = 6    ,
            mit     = 2000 ,
            mfu     = 3000 ,
            ke_m_in = 3.0  ,
            ls      = 75
    );

OPTIONS LS = &ls ; 
title1 &ti ; 

data position ;
    infile &dfn ;
    input
        %do ga = 1 %to &gai ;
            %do ke = 1 %to &kei ;
                V&ga&ke
            %end ;
        %end;
    ;
run ;

PROC CALIS UCOV AUG NOINT MAXITER = &mit MAXFUNC = &mfu ;

    LINEQS

        %do ga = 1 %to &gai ;
            %do ke = 1 %to &kei ;
                V&ga&ke = K&ke ( &ke_m_in ) INTERCEP + H&ke F1&ga + B&ke F2&ga  + E&ga&ke ,
            %end ;
        %end ;
        %do ga = 1 %to &gai ;
            %do ji = 1 %to 2 ;
                F&ji&ga = H&ga&ji (0.0) INTERCEP + L&ga&ji F&ji + D&ga&ji ,
            %end ;
        %end;
        F1 = D1 ,
        F2 = D2 ;

    STD

        %do ga = 1 %to &gai ;
            %do ji = 1 %to 2 ;
                D&ga&ji = PSI&ga&ji ,
            %end;
            %do ke = 1 %to &kei ;
                E&ga&ke = DEL&ga&ke ,
            %end ;
        %end;
        D1 = 1 ,
        D2 = 1 ;

    COV D1 D2 = 0.0 ;

    BOUNDS -1.0 <
                    %do ji = 1 %to 2 ;
                        %do ga = 1 %to &gai ;
                            L&ga&ji
                        %end ;
                    %end ;
                < 1.0 ;
    %do ga = 1 %to &gai ;
        %do ji = 1 %to 2 ;
            PSI&ga&ji = 1 - L&ga&ji * L&ga&ji ;
        %end ;
    %end;
    %do ji = 1 %to 2 ;
        H1&ji =
        %do ga = 2 %to &gai ;
            -H&ga&ji
        %end;
       ;
    %end;
RUN;
%mend position;


/**************************************************************

 fpr [fpr 1776] 多相・ＳＤデータの解析 (Fri, 29 Sep 2000) より

***************************************************************

昨年夏に以下のような記事を書きました．

[fpr 1526] MAP
>因子分析を使用した製品ポジショニング・プロダクトマップ・ＳＤ法
>など対象・形容詞・人のデータの分析方法の工夫・改良に興味があり
>ます（工夫や改良に興味があるのに小生自身は実際の分析経験は多い
>ほうではありません）．
>経験のある方にお伺いしたいのですが，実際にポジショニングを行っ
>ていて「不自由に感じたこと」「こういうことができたらいいなあ」
>「こんなことできないかなあ」ということ，がありましたら教えて頂
>けないでしょうか．

その後この記事にいろいろな意見を頂き，大変参考になりました．この
場を借りて御礼申し上げます．このたび頂いた意見を元に３相データの
ためのポジショニング分析法を考案し，１１月の日本心理学会（京都大
学）の小講演で発表することになりました．

司会者 楠見孝 京都大学 
講演者 豊田秀樹 早稲田大学
題目 共分散構造分析による多相・ＳＤデータの解析 
１１月７日１３：００から１４：００まで
国立京都国際会館１F，ROOM C-2
要旨
ＳＤデータ(semantic differential data)は「被験者」×「尺度」×「
概念」の形式の３相データである．ＳＤ法は，基礎研究ばかりでなく，
ポジショニング分析を通じて，広告効果測定・パッケージテスト・ネー
ミングテスト・コンセプト開発・ライフスタイル分類 (後藤, 1996) な
ど，産業心理学分野でも頻繁に，かつ広汎に利用されている．しかし，
従来，ＳＤデータが３相データのまま解析されることは，極めて希であ
った．平均を計算したり，「被験者」×「概念」を 1 つの相にまとめた
りして，3 相データの持つ情報を利用せずに，2 相データに縮退させて
から分析することが多かった．この現状に対し，海保・加藤(1999, p146)
は「これほどまでにＳＤ法が利用されると，もはや技法そのものの改善
はありえないように思われるが，実は，まだうまい方法が見つかってい
ないデータ解析上の問題が１つある．それは，３次元データを一括して
多変量解析にかける手法」だと問題点を述べている．
本講演の目的は，その要請に応えるために，特に明確な学問的仮説がな
い状況で，３相データのまま，探索的にＳＤデータを分析する汎用的な
手法を提案することである．

手法はSASのマクロで書いてあります．講演の後で使ってみたい方のため
に，予め，マクロをこのMLで配布しておきます．営利目的でなく学習・研
究に使用する限りにおいて再配布自由（奨励）とします．使い方は講演の
中で解説します．

*****************************************************************/